DOUBLE PRECISION FUNCTION iau_GMST82 ( DJ1, DJ2 )
*+
* - - - - - - - - - - -
* i a u _ G M S T 8 2
* - - - - - - - - - - -
*
* Universal Time to Greenwich Mean Sidereal Time (IAU 1982 model).
*
* This routine is part of the International Astronomical Union's
* SOFA (Standards of Fundamental Astronomy) software collection.
*
* Status: canonical model.
*
* Given:
* DJ1, DJ2 d UT1 Julian Date (see note)
*
* Returned:
* iau_GMST82 d Greenwich mean sidereal time (radians)
*
* Notes:
*
* 1) The UT1 epoch DJ1+DJ2 is a Julian Date, apportioned in any
* convenient way between the arguments DJ1 and DJ2. For example,
* JD(UT1)=2450123.7 could be expressed in any of these ways,
* among others:
*
* DJ1 DJ2
*
* 2450123.7D0 0D0 (JD method)
* 2451545D0 -1421.3D0 (J2000 method)
* 2400000.5D0 50123.2D0 (MJD method)
* 2450123.5D0 0.2D0 (date & time method)
*
* The JD method is the most natural and convenient to use in
* cases where the loss of several decimal digits of resolution
* is acceptable. The J2000 and MJD methods are good compromises
* between resolution and convenience. The date & time method is
* best matched to the algorithm used: maximum accuracy (or, at
* least, minimum noise) is delivered when the DJ1 argument is for
* 0hrs UT1 on the day in question and the DJ2 argument lies in the
* range 0 to 1, or vice versa.
*
* 2) The algorithm is based on the IAU 1982 expression. This is always
* described as giving the GMST at 0 hours UT1. In fact, it gives the
* difference between the GMST and the UT, the steady 4-minutes-per-day
* drawing-ahead of ST with respect to UT. When whole days are ignored,
* the expression happens to equal the GMST at 0 hours UT1 each day.
*
* 3) In this routine, the entire UT1 (the sum of the two arguments DJ1
* and DJ2) is used directly as the argument for the standard formula,
* the constant term of which is adjusted by 12 hours to take account
* of the noon phasing of Julian Date. The UT1 is then added, but
* omitting whole days to conserve accuracy.
*
* 4) The result is returned in the range 0 to 2pi.
*
* Called:
* iau_ANP normalize angle into range 0 to 2pi
*
* References:
*
* Transactions of the International Astronomical Union,
* XVIII B, 67 (1983).
*
* Aoki et al., Astron.Astrophys., 105, 359-361 (1982).
*
* This revision: 2020 January 12
*
* SOFA release 2021-05-12
*
* Copyright (C) 2021 IAU SOFA Board. See notes at end.
*
*-----------------------------------------------------------------------
IMPLICIT NONE
DOUBLE PRECISION DJ1, DJ2
* Seconds of time to radians
DOUBLE PRECISION DS2R
PARAMETER ( DS2R = 7.272205216643039903848712D-5 )
* Reference epoch (J2000.0), JD
DOUBLE PRECISION DJ00
PARAMETER ( DJ00 = 2451545D0 )
* Seconds per day, days per Julian century
DOUBLE PRECISION D2S, DJC
PARAMETER ( D2S = 86400D0, DJC = 36525D0 )
* Coefficients of IAU 1982 GMST-UT1 model
DOUBLE PRECISION A, B, C, D
PARAMETER ( A = 24110.54841D0 - D2S/2D0,
: B = 8640184.812866D0,
: C = 0.093104D0,
: D = -6.2D-6 )
* The first constant, A, has to be adjusted by 12 hours because the UT1
* is supplied as a Julian date, which begins at noon.
DOUBLE PRECISION D1, D2, T, F
DOUBLE PRECISION iau_ANP
* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
* Julian centuries since fundamental epoch.
IF ( DJ1 .LT. DJ2 ) THEN
D1 = DJ1
D2 = DJ2
ELSE
D1 = DJ2
D2 = DJ1
END IF
T = ( D1 + ( D2-DJ00 ) ) / DJC
* Fractional part of JD(UT1), in seconds.
F = D2S * ( MOD(D1,1D0) + MOD(D2,1D0) )
* GMST at this UT1.
iau_GMST82 = iau_ANP ( DS2R * ( (A+(B+(C+D*T)*T)*T) + F ) )
* Finished.
*+----------------------------------------------------------------------
*
* Copyright (C) 2021
* Standards Of Fundamental Astronomy Board
* of the International Astronomical Union.
*
* =====================
* SOFA Software License
* =====================
*
* NOTICE TO USER:
*
* BY USING THIS SOFTWARE YOU ACCEPT THE FOLLOWING SIX TERMS AND
* CONDITIONS WHICH APPLY TO ITS USE.
*
* 1. The Software is owned by the IAU SOFA Board ("SOFA").
*
* 2. Permission is granted to anyone to use the SOFA software for any
* purpose, including commercial applications, free of charge and
* without payment of royalties, subject to the conditions and
* restrictions listed below.
*
* 3. You (the user) may copy and distribute SOFA source code to others,
* and use and adapt its code and algorithms in your own software,
* on a world-wide, royalty-free basis. That portion of your
* distribution that does not consist of intact and unchanged copies
* of SOFA source code files is a "derived work" that must comply
* with the following requirements:
*
* a) Your work shall be marked or carry a statement that it
* (i) uses routines and computations derived by you from
* software provided by SOFA under license to you; and
* (ii) does not itself constitute software provided by and/or
* endorsed by SOFA.
*
* b) The source code of your derived work must contain descriptions
* of how the derived work is based upon, contains and/or differs
* from the original SOFA software.
*
* c) The names of all routines in your derived work shall not
* include the prefix "iau" or "sofa" or trivial modifications
* thereof such as changes of case.
*
* d) The origin of the SOFA components of your derived work must
* not be misrepresented; you must not claim that you wrote the
* original software, nor file a patent application for SOFA
* software or algorithms embedded in the SOFA software.
*
* e) These requirements must be reproduced intact in any source
* distribution and shall apply to anyone to whom you have
* granted a further right to modify the source code of your
* derived work.
*
* Note that, as originally distributed, the SOFA software is
* intended to be a definitive implementation of the IAU standards,
* and consequently third-party modifications are discouraged. All
* variations, no matter how minor, must be explicitly marked as
* such, as explained above.
*
* 4. You shall not cause the SOFA software to be brought into
* disrepute, either by misuse, or use for inappropriate tasks, or
* by inappropriate modification.
*
* 5. The SOFA software is provided "as is" and SOFA makes no warranty
* as to its use or performance. SOFA does not and cannot warrant
* the performance or results which the user may obtain by using the
* SOFA software. SOFA makes no warranties, express or implied, as
* to non-infringement of third party rights, merchantability, or
* fitness for any particular purpose. In no event will SOFA be
* liable to the user for any consequential, incidental, or special
* damages, including any lost profits or lost savings, even if a
* SOFA representative has been advised of such damages, or for any
* claim by any third party.
*
* 6. The provision of any version of the SOFA software under the terms
* and conditions specified herein does not imply that future
* versions will also be made available under the same terms and
* conditions.
*
* In any published work or commercial product which uses the SOFA
* software directly, acknowledgement (see www.iausofa.org) is
* appreciated.
*
* Correspondence concerning SOFA software should be addressed as
* follows:
*
* By email: sofa@ukho.gov.uk
* By post: IAU SOFA Center
* HM Nautical Almanac Office
* UK Hydrographic Office
* Admiralty Way, Taunton
* Somerset, TA1 2DN
* United Kingdom
*
*-----------------------------------------------------------------------
END